epbas.lgb.hu :: Enterprise-128 EXOS file analyzer, lister and disassembler
File name: /tmp/phpikw1DI (37334 bytes)
Options: bin=None cset='HUN' dasm='' html='' info='' out='/tmp/phpikw1DI.out'
EP-ASCII: HUN
EXOS header pos/serial: #0 at 0x0
EXOS type/header: 0x4 [00 04 B6 91 00 00 00 00 00 00 00 00 00 00 00 00]
EXOS type determined: IS-BASIC program (single)
Program: 0x0, size: 0x91b6 bytes.
1 PROGRAM "FourMile.bas"
2 REM Modified in 2002 by Chris Charla
3 RANDOMIZE
4 TEXT 80
5 CLEAR FONT:SET 8,1:SET 26,1:SET 7,0:SET 24,40:SET 25,2:SET 22,2:SET 23,0
6 SET #102:PALETTE32,183,32,123,32,89,4,255:SET 27,32
7 DIM RM(31,4),OB(15,2),VT(36)
8 STRING L$(1TO15,1TO2)*72,VB$(0TO36)*3
9 LET ER=0:LET R=17:LET SF,AL,PA,DT,EX,BD,MD,BR,GL,FT,LM,AC,CC=1
10 PRINT "Four Mile Island";CHR$(241):SET #102:INK3:PRINT "Original code by Tom Lartiot";CHR$(241):PRINT
11 LET TD=2:LET LS=35
12 LET ML,MP=-1
13 FOR X=1TO31
14 FOR Y=1TO4
15 READ RM(X,Y)
16 NEXT
17 NEXT
18 FOR X=1TO15
19 FOR Y=1TO2
20 READ OB(X,Y)
21 NEXT
22 NEXT
23 FOR Z=1TO15
24 FOR A=1TO2
25 READ L$(Z,A)
26 NEXT
27 NEXT
28 FOR X=1TO36
29 READ VB$(X)
30 NEXT X
31 FOR X=1TO36
32 READ VT(X)
33 NEXT X
34 SET FKEY1"look"&CHR$(13):SET FKEY2"examine ":SET FKEY3"inventory"&CHR$(13):SET FKEY4"diagnose"&CHR$(13):SET FKEY5"apply ":SET FKEY6"take ":SET FKEY7"drop ":SET FKEY8"help"&CHR$(13)
35 SET FKEY9"wait"&CHR$(13):SET FKEY10"break ":SET FKEY11"open ":SET FKEY12"close ":SET FKEY13"threaten ":SET FKEY14"shoot ":SET FKEY15"talk ":SET FKEY16"quit"
36 OPEN #1:"video:"
37 SET #1:PALETTE28,183,156,255
38 DISPLAY #1:AT25FROM1TO2
39 PRINT #1:CHR$(27);"o wait break open close threaten shoot talk quit ";:SET #1:INK3:PRINT #1:" look examine inventory diagnose apply take drop help ";
40 GOTO 591
41 LET CC=CC+1
42 PRINT
43 IF R=ERTHEN 49
44 GOSUB 367
45 REM
46 FOR X=1TO15
47 IF OB(X,2)=RTHENGOSUB 454
48 NEXT
49 REM
50 IF AL=1THENSET #102:INK5:PRINT "A deafening alarm siren blares from speakers overhead.":PRINT :SET #102:INK1
51 GOSUB 558
52 IF EX=0THENLET LS=LS-1
53 IF LS=20THENLET TD=1
54 IF LS=10THENLET TD=0
55 IF LS=0THEN 551
56 IF ML=RANDMP<0THEN 565
57 IF MP=RTHENSET #102:INK5:PRINT "Marchand is here, looking nervous.":SET #102:INK1
58 IF LM<1THENLET LM=LM-1
59 IF LM=-2THEN 513
60 IF CC=250THEN 154
61 SET #102:INK3:INPUT PROMPT"What now? ":M$
62 SET #102:INK1
63 LET M1$,M2$="":LET M2,X=0:LET M$=LTRIM$(RTRIM$(LCASE$(M$)))
64 LET L=LEN(M$)
65 IF M$(1:3)="wai"THENPRINT "Waiting...":GOTO 41
66 IF M$(1:3)="qui"THEN 602
67 FOR I=1TOL
68 LET A$=M$(I:I):LET A=ORD(A$)
69 IF A$<>" "THEN 72
70 IF M2$<>""THEN 75
71 LET X=1:GOTO 74
72 IF X=0THENLET M1$=M1$&A$:GOTO 74
73 LET M2$=M2$&A$
74 NEXT
75 IF M1$=""THENPRINT "Input, please!":GOTO 61
76 LET MG$=M1$:LET ML$=M1$(1:3):LET M1$=ML$
77 LET MM$=M2$(1:3)
78 LET M2$=MM$
79 GOSUB 612
80 IF LEN(M1$)=1THEN 460
81 FOR X=1TO36
82 IF VB$(X)=M1$THENLET T=VT(X):GOTO 85
83 NEXT
84 PRINT "I'm sorry, i don't know how to do that.":PRINT "For a complete list of accepted verbs, type 'help.'":GOTO 41
85 ON TGOTO 86, 94, 122, 157, 158, 163, 177, 196, 216, 227, 246, 256, 269, 288, 301, 344, 348, 356
86 REM go
87 IF M1$="acc"THEN 196
88 IF M1$="nor"ORM2$="nor"THENLET M1$="n":GOTO 80
89 IF M1$="sou"ORM2$="sou"THENLET M1$="s":GOTO 80
90 IF M1$="eas"ORM2$="eas"THENLET M1$="e":GOTO 80
91 IF M1$="wes"ORM2$="wes"THENLET M1$="w":GOTO 80
92 PRINT "I'm sorry, i didn't understand. You must 'go' a direction ('go north') or, you can simply type the direction ('north') or letter ('n')."
93 GOTO 41
94 REM talk
95 IF M2$=""ORM2$="sel"THENPRINT "You mumble to yourself. Feel better?":GOTO 41
96 IF M2$="mar"ANDMP=RTHEN 111
97 IF M2$="mar"ANDML=RTHEN 101
98 IF M2$="cor"ANDR=10THEN 100
99 PRINT "You're wasting your breath.":GOTO 41
100 PRINT "You're a good listener, did you know that?":GOTO 41
101 LET K=RND(4)+1
102 ON KGOTO 103, 105, 107, 109
103 PRINT "You attempt to reason with Marchand, convince him there's no escape."
104 PRINT "His reply: 'you don't scare me, cartright.' and with that, he's gone.":GOTO 41
105 PRINT "You tell Marchand his situation is hopeless."
106 PRINT "'Non, mon ami, you do not threaten me. I have nothing but hope.'":GOTO 41
107 PRINT "Before you can speak, Marchand makes the 'shh!' gesture with his fingers."
108 PRINT "Against his lips. He grins a crazy smile and rushes away.":GOTO 41
109 PRINT "You look at him and ask 'why?'"
110 PRINT "He shakes his head slightly. 'You were in vladistan, and still you have to ask?'":GOTO 41
111 LET D=RND(4)+1
112 ON DGOTO 113, 115, 117, 119
113 PRINT "You turn to him: 'Marchand, there's no way out. Defuse the bomb.'"
114 PRINT "He smiles. 'Ahh, mon ami, you have been in tighter situations and escaped, no? Moi aussi.' I think i will wait a bit before i start to believe that i am truly trapped.":GOTO 41
115 PRINT "You thrust the gun under his chin. 'defuse it!'"
116 PRINT "Marchand pushes the barrel away. 'Or what? are you going to shoot me? i deed not think so.":GOTO 41
117 PRINT "You look at him: 'I should have killed you in vladistan.'"
118 PRINT "He smirks. 'If you had had the courage to shoot me then, i wouldn't be so confident now, mon ami!":GOTO 41
119 PRINT "You give up. 'Fine Marchand, don't disarm the bomb. We can both let god finish what he started in vladistan.'"
120 PRINT "He laughs. 'Mon ami, as long as there is the slightest chance of escape, i will do nothing to disarm anything.":GOTO 41
121 GOTO 41
122 REM examine
123 IF M2$=""THEN 150
124 IF R=14ANDOB(7,2)<0THEN 149
125 IF R=14ANDOB(7,2)>-1THENPRINT "You don't find anything special.":GOTO 41
126 FOR X=1TO15
127 IF M2$=L$(X,2)(1:3)THEN 130
128 NEXT
129 PRINT "You don't see that thing here.":GOTO 41
130 IF X=7AND(OB(7,2)=0OROB(7,2)=R)THENPRINT "It's a very long series of digits written in longhand.":GOTO 41
131 IF X=3AND(OB(3,2)=0OROB(3,2)=R)THENPRINT "It's got instructions:":PRINT "'Remove backing and apply patch. Allow 24 hours for glue to set, or it may shift under certain conditions.'":GOTO 41
132 IF X=4AND(OB(4,2)=0OROB(4,2)=R)THENPRINT "It's an ordinary roll of duct tape, though the brand name is 'duck tape.' cute.":GOTO 41
133 IF X=5AND(OB(5,2)=0OROB(5,2)=R)THENPRINT "It's a modern magnetic access card. Pretty cool!":GOTO 41
134 IF X=2AND(OB(2,2)=0OROB(2,2)=R)THENPRINT "This is a mean looking crowbar. Heavy duty.":GOTO 41
135 IF X=8ANDR=15THENPRINT "The safe is a compact model.":GOTO 41
136 IF X=6AND(OB(6,2)=0OROB(6,2)=R)THEN 147
137 IF X=10ANDR=10THENPRINT "grim.":GOTO 41
138 IF X=11ANDR=12THENPRINT "You study the maze of the reactor... None of the areas seem to have the same exact same pattern of exits.":GOTO 41
139 IF X=1AND(OB(1,2)=0OROB(1,2)=R)ANDPA=1THENPRINT "It's a standard issue radiation suit, essential for going on the reactor floor. Unfortunately (for you and the previous owner) it has a bullet hole in it.":GOTO 41
140 IF X=9ANDR=5THENPRINT "The case is locked tight.":GOTO 41
141 IF X=1AND(OB(1,2)=0OROB(1,2)=R)ANDPA=0THENPRINT "A patch is covering the bullet hole.":GOTO 41
142 IF X=1AND(OB(1,2)=0OROB(1,2)=R)ANDDT=0THENPRINT "Several layers of duct tape are securing the patch. It should hold.":GOTO 41
143 IF X=12ANDR=15THENPRINT "It's a pretty nice photo, showing the control building and cooling tower.":GOTO 41
144 IF X=15ANDR=1THEN 151
145 PRINT "You don't see that here.":GOTO 41
146 GOTO 41
147 IF BR>0THENPRINT "It's got one bullet in it.":GOTO 41
148 PRINT "It's empty. Marchand doesn't know that, of course...":GOTO 41
149 PRINT "As you look through the secretary's papers, you find a combo on a 'post-it,' which you quickly slip into your pocket.":LET OB(7,2)=0:GOTO 41
150 LET ER=0:GOTO 41
151 PRINT "The bomb is fastened securely to the main console."
152 PRINT "As you look at it, you are again impressed with Marchand's skills. It is a masterpiece of tamper-proof explosives."
153 PRINT "To touch it is to detonate it.":GOTO 41
154 IF BD=0THENLET CC=100:GOTO 41
155 PRINT "You knew you had a time limit, you just didn't know how much. As you hear the bomb go off, you realized you just reached it."
156 PRINT "You have failed.":GOTO 602
157 LET M1$="i":GOTO 80
158 IF TD=2THENPRINT "As always, you are in top physical condition."
159 IF TD=1THENPRINT "You feel a bit woozy; sadly, it's probably radiation sickness."
160 IF TD=0THENPRINT "You feel really, really, sick."
161 PRINT "Turn:";CC
162 GOTO 42
163 REM
164 IF M2$="pat"THEN 167
165 IF M2$="tap"THEN 171
166 PRINT "You don't need to put or apply that to anything.":GOTO 41
167 IF OB(1,2)=0THENPRINT "You can't put on the patch while wearing the suit.":GOTO 41
168 IF OB(1,2)=RTHEN 170
169 PRINT "The kit only works on a radiation suit.":GOTO 41
170 LET PA=0:PRINT "The patch kit has a lot of instructions on it, but it's pretty simple to remove the paper backing and stick it over the hole. The patch feels a little loose once it's on, but maybe it's supposed to.":GOTO 41
171 IF OB(1,2)=ROROB(1,2)=0THEN 173
172 PRINT "That isn't something you can fix with duct tape, sorry.":GOTO 41
173 IF PA=0THEN 176
174 PRINT "You consider using some duct tape to patch the hole in the rad. suit, but as much as you trust duct tape, in this case it seems like it might be ";
175 PRINT "better to at least back it up with something to block the radiation.":GOTO 41
176 LET DT=0:PRINT "You slather duct tape over the patch. That ought to hold it steady.":GOTO 41
177 REM shoot/kill
178 IF M2$="mar"ANDOB(6,2)<>0THENPRINT "You are trained in countless methods of lethal, unarmed combat."
179 IF M2$="mar"ANDOB(6,2)<>0THENPRINT "But so is Marchand. Not worth it. You need an equalizer.":GOTO 41
180 IF M2$="mar"THEN 188
181 IF M2$="cor"THENPRINT "The stress must be getting to you, cartright.":GOTO 41
182 IF M2$="sel"ORM2$="me"THENPRINT "The coward's way out?ifyou insist.":GOTO 544
183 IF M2$=""THENPRINT "Everyone likes a killer attitude, but please, more focus.":GOTO 41
184 IF M2$="bom"THEN 191
185 IF M2$="gun"THEN 192
186 IF M2$="sui"THEN 195
187 PRINT "Great killer instinct. But you don't need to shoot, kill, maim, or harm that.":GOTO 41
188 IF BR>0THENPRINT "You level the gun at Marchand. Almost by itself, the gun fires.":LET MD=0:GOTO 535
189 IF BR=0THENPRINT "The gun is empty. But Marchand doesn't know that. He will, of course, if you try to beat him to death with it, which is basically your only option at this point.":GOTO 41
190 IF BR=0THENPRINT "Click":GOTO 41
191 IF BR>0THENPRINT "Shooting a bomb you were sent to disarm. Not a good idea.":GOTO 195
192 IF OB(6,2)<>0THENPRINT "You don't have a gun.":GOTO 41
193 IF BR>0THENPRINT "The gun fires with a ferocious report!":LET BR=0:GOTO 41
194 IF BR=0THENPRINT "Click":GOTO 41
195 PRINT "One of the reasons you rose so high in the secret agent ranks, cartright, is because you don't do things like that.":GOTO 41
196 REM access
197 IF M2$=""THENPRINT "You need to type a direction!":GOTO 41
198 FOR X=1TO4
199 IF RM(R,X)=-1THEN 202
200 NEXT
201 PRINT "There's no doorway here that requires an access card.":GOTO 41
202 IF OB(5,2)<>0THENPRINT "You don't have an access card.":GOTO 41
203 IF M2$="sou"ORM2$="s"THEN 210
204 IF M2$="nor"ORM2$="n"THEN 206
205 PRINT "There's no doorway in that direction that requires a card.":GOTO 41
206 IF R=2THENLET ER=R:LET R=1:GOTO 214
207 IF R=7THENLET ER=R:LET R=5:GOTO 214
208 IF R=21THENLET ER=R:LET R=10:GOTO 214
209 IF R=22THENLET ER=R:LET R=21:GOTO 214
210 IF R=1THENLET ER=R:LET R=2:GOTO 214
211 IF R=5THENLET ER=R:LET R=7:GOTO 214
212 IF R=10THENLET ER=R:LET R=21:GOTO 214
213 IF R=21THENLET ER=R:LET R=22:GOTO 214
214 PRINT "You slide the access card through the reader, and move through the automatic blast door as it opens. It slides shut with finality behind you."
215 GOTO 41
216 REM drop
217 IF M2$="all"THEN 226
218 FOR X=1TO15
219 IF M2$=L$(X,2)(1:3)THEN 222
220 NEXT
221 PRINT "You can drop what you can't take!":GOTO 41
222 IF OB(X,2)=0THEN 224
223 PRINT "You're not holding that!":GOTO 41
224 REM
225 LET OB(X,2)=R:PRINT "Dropped.":GOTO 41
226 PRINT "You can't use the word 'all' with objects, sorry.":GOTO 41
227 IF M2$="all"THEN 243
228 FOR X=1TO15
229 IF M2$=L$(X,2)(1:3)THEN 232
230 NEXT
231 PRINT "Sorry, you can't take that.":GOTO 41
232 IF OB(X,2)=-4ANDR=5THENPRINT "The case is fastened securely to the wall.":GOTO 41
233 IF OB(X,2)=-5ANDR=10THENPRINT "Have you no respect for the dead!":GOTO 41
234 IF OB(X,2)=-3ANDR=12THENPRINT "The blue prints are mounted securely.":GOTO 41
235 IF OB(X,2)=-2ANDR=15THENPRINT "Sorry, you can't take that.":GOTO 41
236 IF OB(X,2)=-7ANDR=15THENPRINT "Worry about art collecting later.":GOTO 41
237 IF OB(X,2)=-9ANDR=1THENPRINT "Unless you built it, you can't disarm it.":GOTO 41
238 IF R=OB(X,2)THEN 241
239 IF OB(X,2)=0THEN 242
240 PRINT "You can't see any ";L$(X,2);" here.":GOTO 41
241 LET OB(X,2)=0:PRINT "You take the ";L$(X,2);".":GOTO 244
242 PRINT "You're already holding it!":GOTO 41
243 PRINT "Sorry, you need to 'take' each item individually.":GOTO 41
244 LET OB(X,1)=0
245 GOTO 41
246 REM
247 IF M2$="saf"THEN 250
248 IF M2$="ala"THEN 251
249 GOTO 41
250 PRINT "Honestly, you have more pressing concerns than making the directors room look neat. Leave the safe alone, and stop the Marchand!":GOTO 41
251 IF R=4THEN 252:PRINT"What alarm switch?":GOTO1000
252 IF AL=0THEN 253:PRINT"It's already off.":GOTO1000
253 PRINT "You shut the alarm switch, and the siren goes mercifully silent."
254 PRINT "The silence is deafening at first, but soon, over the speakers you hear the sound of footsteps! It's Marchand, looking for the exit!"
255 LET AL=0:GOTO 41
256 REM open
257 IF M2$="saf"THEN 293
258 IF M2$="cas"THEN 263
259 IF M2$="loc"THEN 263
260 IF M2$<>""THEN 262
261 PRINT "You need to use an object with the verb 'unlock.'":GOTO 41
262 PRINT "There's nothing to unlock here.":GOTO 41
263 IF R=5THEN 265
264 PRINT "You can't see a gun case here.":GOTO 41
265 IF GL=0THENPRINT "The gun case is already open!":GOTO 41
266 PRINT "The gun locker is secured with a wicked deadbolt."
267 PRINT "You'd need a crowbar to break it open without the key."
268 GOTO 41
269 REM break
270 IF M2$="cas"ANDOB(2,2)=0THEN 282
271 IF M2$="cas"THEN 277
272 IF M2$="bom"THEN 280
273 IF M2$="doo"THEN 278
274 IF M2$="saf"THEN 279
275 IF M2$="acc"THEN 286
276 PRINT "You don't need to break that.":GOTO 41
277 PRINT "You'll need more than your bare hands to do that.":GOTO 41
278 PRINT "The door is too well armored to be broken.":GOTO 41
279 PRINT "Yhe safe is too well made to yield.":GOTO 41
280 PRINT "i'm afraid brute force isn't going to solve this one, old boy."
281 PRINT "If you tried to smash the bomb, you would only succeed in detonating it faster.":GOTO 41
282 IF GL=0THENPRINT "The locker is already open!":GOTO 41
283 PRINT "You jam the crowbar between the lock and the hinge."
284 PRINT "After a few whacks, the lock suddenly gives way, and the gun locker door flies open, and a gun comes out.":LET GL=0
285 LET OB(6,2)=5:GOTO 41
286 GOTO 504
287 GOTO 41
288 REM open
289 IF M2$="ala"THEN 300
290 IF M2$="saf"THEN 293
291 IF M2$="cas"ORM2$="loc"THEN 265
292 PRINT "You don't need to open that.":GOTO 41
293 IF OB(7,2)=0ANDR=15THEN 297
294 IF R=15THENPRINT "The combination is so long that you need to be holding it.":GOTO 41
295 PRINT "You don't see a safe here.":GOTO 41
296 PRINT "It to have any hope of opening the safe.":GOTO 41
297 IF SF=0THENPRINT "It's already open.":GOTO 41
298 PRINT "After carefully entering the difficult combo, the safe pops open!"
299 LET OB(5,2)=R:LET SF=0:PRINT :GOTO 46
300 PRINT "Nothing could make you turn that alarm back on. If you survive, your hearing is probably shot as it is.":GOTO 41
301 REM
302 IF M2$=""THENPRINT "Brave talk, but you need to threaten someone!":GOTO 41
303 IF M2$="mar"ANDML<>RTHENPRINT "You must find Marchand before you threaten him.":GOTO 41
304 IF M2$="mar"ANDML=RTHEN 312
305 IF M2$="cor"THENPRINT "The corpse is scared stiff.":GOTO 41
306 IF M2$="bom"THENPRINT "Trying to scare the bomb into deactivating doesn't work.":GOTO 41
307 IF M2$="n"ORM2$="nor"THEN 320
308 IF M2$="s"ORM2$="sou"THEN 329
309 IF M2$="e"ORM2$="eas"THEN 338
310 IF M2$="w"ORM2$="wes"THEN 341
311 PRINT "Calm down. you don't need to threaten that.":GOTO 41
312 IF OB(6,2)=0THEN 314
313 PRINT "You need something to threaten Marchand with!":GOTO 41
314 PRINT "You level the gun at Marchand. 'Scared? you should be.'"
315 PRINT "Marchand looks at you. 'What do you think you will do? kill me?"
316 PRINT "I doubt it.' He doesn't look as certain as he sounds."
317 LET ML=-1:LET MP=R:PRINT "and he doesn't leave the room."
318 PRINT :PRINT "ÉNote: to command Marchand to move, type 'threaten south,' etc.Ü"
319 PRINT "ÉYou will automatically use the access card when needed.Ü":GOTO 41
320 IF MP<>RTHENPRINT "Marchand isn't here to threaten.":GOTO 41
321 IF RM(R,1)<0THEN 324
322 IF RM(R,1)>0THENLET ER=R:LET R=RM(R,1):LET MP=R:PRINT "You push Marchand ahead of you.":GOTO 41
323 PRINT "As much as Marchand is afraid of your gun, he can't walk through a wall.":GOTO 41
324 IF OB(5,2)<>0THENPRINT "You can't go that way without and access card.":GOTO 41
325 IF R=2THENLET ER=R:LET R=1:LET MP=R:PRINT "You slide the access card through the slot and push Marchand through.":GOTO 41
326 IF R=7THENLET ER=R:LET R=5:LET MP=R:PRINT "You slide the access card through the slot and push Marchand through.":GOTO 41
327 IF R=21THENLET ER=R:LET R=10:LET MP=R:PRINT "You slide the access card through the slot and push Marchand through.":GOTO 41
328 IF R=22THENLET ER=R:LET R=21:LET MP=R:PRINT "You slide the access card through the slot and push Marchand through.":GOTO 41
329 IF MP<>RTHENPRINT "Marchand isn't here to threaten.":GOTO 41
330 IF RM(R,2)<0THEN 333
331 IF RM(R,2)>0THENLET ER=R:LET R=RM(R,2):LET MP=R:PRINT "You push Marchand ahead of you.":GOTO 41
332 PRINT "As much as Marchand is afraid of your gun, he can't walk through a wall.":GOTO 41
333 IF OB(5,2)<>0THENPRINT "You can't go that way without and access card.":GOTO 41
334 IF R=1THENLET ER=R:LET R=2:LET MP=R:PRINT "You slide the access card through the slot and push Marchand through.":GOTO 41
335 IF R=5THENLET ER=R:LET R=7:LET MP=R:PRINT "You slide the access card through the slot and push Marchand through.":GOTO 41
336 IF R=10THENLET ER=R:LET R=21:LET MP=R:PRINT "You slide the access card through the slot and push Marchand through.":GOTO 41
337 IF R=21THENLET ER=R:LET R=22:LET MP=R:PRINT "You slide the access card through the slot and push Marchand through.":GOTO 41
338 IF MP<>RTHENPRINT "Marchand isn't here to threaten.":GOTO 41
339 IF RM(R,3)<>0THENLET ER=R:LET R=RM(R,3):LET MP=R:PRINT "You push Marchand ahead of you.":GOTO 41
340 PRINT "As much as Marchand is afraid of your gun, he can't walk through a wall.":GOTO 41
341 IF MP<>RTHENPRINT "Marchand isn't here to threaten.":GOTO 41
342 IF RM(R,4)<>0THENLET ER=R:LET R=RM(R,4):LET MP=R:PRINT "You push Marchand ahead of you.":GOTO 41
343 PRINT "As much as Marchand is afraid of your gun, he can't walk through a wall.":GOTO 41
344 REM help
345 PRINT "Four Mile Island accepts the following verbs ('use' isn't one of them):":SET #102:INK3
346 PRINT "go, north, south, east, west, talk, read, look, search, examine, inventory, health, diagnose, apply, shoot, kill, access, put, drop, ";
347 PRINT "remove, get, take, close, unlock, break, pry, smash, help, open, threaten, scare, wait and quit":SET #102:INK1:GOTO 42
348 REM xyz
349 CLEAR SCREEN
350 PRINT "Okay, you asked for it...":PRINT
351 SET #102:INK1:PRINT "You are in a 3d maze of twisty little passageways, all alike."
352 PRINT "Exits lead in all directions."
353 SET #102:INK3:INPUT PROMPT"What now? ":PO$
354 SET #102:INK1:PRINT "Just kidding..."
355 LET ER=0:PRINT :GOTO 42
356 IF M2$="cor"ANDR=10THEN 360
357 IF M2$="mar"ANDML=RTHENPRINT "He's got a beard! Gross!":GOTO 41
358 PRINT "What would your betrothed, carrie shepherd, think if she knew you, drake cartright, master spy, resorted to profanity as soon as things got tough? pull yourself together, man!"
359 GOTO 41
360 PRINT "No one is around but Marchand, and he won't tell... at last, a chance to live out your deepest fantasy..."
361 PRINT "*****parser interupt!*****"
362 PRINT "ÉI'm sorry; i don't care what the designer or you the playerÜ"
363 PRINT "Éhave in mind, but i have standards, and you just exceeded themÜ"
364 PRINT "Éyou sick weirdo.Ü"
365 PRINT "*--éÉ*2üadventure simulation abortedéÜ*2ü--*"
366 GOTO 602
367 IF R>25THEN 370
368 SET #102:INK7
369 ON RGOTO 373, 375, 377, 379, 384, 386, 388, 390, 392, 394, 398, 400, 402, 404, 406, 411, 413, 415, 417, 419, 421, 423, 427, 429, 431
370 LET G=R:LET G=G-25
371 SET #102:INK7
372 ON GGOTO 433, 435, 437, 439, 441, 443
373 PRINT "Reactor control ":SET #102:INK1
374 PRINT "The main control area for the entire plant. If something goes wrong here, like the bomb on the console going off, say, a melt-down - and the deaths of thousands - is inevitable. ":GOTO 452
375 PRINT "Outside control ";:GOSUB 445
376 PRINT "You are in the hallway outside the sealed door to the plant control room.":GOTO 452
377 PRINT "Reactor corridor west ";:GOSUB 445
378 PRINT "This is an east-west hallway. South is the break room. Blood spatters the walls.":GOTO 452
379 PRINT "Facility control ";:GOSUB 445
380 PRINT "This is where the security of the facility is monitored. A gunfight took place a gunfight took place here: monitors are shot up. The threat board is all red."
381 PRINT "The main alarm switch is set to ";
382 IF AL=1THENPRINT "'open.'":GOTO 452
383 IF AL=0THENPRINT "'closed.'":GOTO 452
384 PRINT "Security ";:GOSUB 445
385 PRINT "This is the main security office. A gun case is mounted on the wall.":GOTO 452
386 PRINT "Central corridor ";:GOSUB 445
387 PRINT "This well worn corridor is the center path through the nuclear plant.":GOTO 452
388 PRINT "Junction ";:GOSUB 445
389 PRINT "This is a four way junction. To the east is the entrance to the reactor. To the south, admin.":GOTO 452
390 PRINT "Reactor corridor e ";:GOSUB 445
391 PRINT "This is the east end of a long hallway. Bullet holes pock the walls.":GOTO 452
392 PRINT "Reactor vestibule ";:GOSUB 445
393 PRINT "To the south lies the reactor.":GOTO 452
394 PRINT "Outside airlock ";:GOSUB 445
395 PRINT "The odor of death is here. One of Marchand's victims is here, ";
396 IF OB(1,1)=1THENPRINT "still clad in a radiation suit that's been pierced by a bullet.":GOTO 452
397 IF OB(1,1)=0THENPRINT :PRINT "although the suit is gone, the bullet hole remains.":GOTO 452
398 PRINT "Admin reception ";:GOSUB 445
399 PRINT "Abandoned in a hurry, this office is a mess.":GOTO 452
400 PRINT "Spare office ";:GOSUB 445
401 PRINT "This spare office has some blue prints in it.":GOTO 452
402 PRINT "Outer office ";:GOSUB 445
403 PRINT "A fairly dull office.":GOTO 452
404 PRINT "Secretary's office ";:GOSUB 445
405 PRINT "This is the office of the director's secretary. It is covered in tiny slips of paper, including those new 'post-it' notes.":GOTO 452
406 PRINT "Director's office ";:GOSUB 445
407 PRINT "This is the office of the director of the plant. A safe, which is ";
408 IF SF=0THEN 410
409 PRINT "locked, is behind an ornate desk. An aerial photo of the plant dominates the south wall.":GOTO 452
410 PRINT "open, is behind an ornate desk. an aerial photo of the plant dominates the south wall.":GOTO 452
411 PRINT "Tunnel north ";:GOSUB 445
412 PRINT "Well, this is it. As soon as you go north through the hole, they're going to weld it shut behind you.":GOTO 452
413 PRINT "Tunnel south ";:GOSUB 445
414 PRINT "The access tunnel leads north.":GOTO 452
415 PRINT "Closet ";:GOSUB 445
416 PRINT "Yep, it's a closet all right.":GOTO 452
417 PRINT "Break room ";:GOSUB 445
418 PRINT "This is where plant employees hang out on break.":GOTO 452
419 PRINT "Bathroom ";:GOSUB 445
420 PRINT "This is the restroom.":GOTO 452
421 PRINT "Airlock ";:GOSUB 445
422 PRINT "This is the airlock. To the south lies the radioactive air of the reactor complex.":GOTO 452
423 PRINT "Reactor floor ";:GOSUB 445
424 PRINT "The radiation is high in here. To the north is the air lock."
425 IF FT=1THENLET FT=0:GOSUB 496
426 GOTO 452
427 PRINT "Reactor ";:GOSUB 445
428 PRINT "It's like a maze in here.":GOTO 452
429 PRINT "Reactor ";:GOSUB 445
430 PRINT "It's like a maze in here.":GOTO 452
431 PRINT "Reactor ";:GOSUB 445
432 PRINT "It's like a maze in here.":GOTO 452
433 PRINT "Outside storage ";:GOSUB 445
434 PRINT "To the south is a storage closet.":GOTO 452
435 PRINT "Reactor ";:GOSUB 445
436 PRINT "It's like a maze in here.":GOTO 452
437 PRINT "Reactor ";:GOSUB 445
438 PRINT "It's like a maze in here.":GOTO 452
439 PRINT "Reactor ";:GOSUB 445
440 PRINT "It's like a maze in here.":GOTO 452
441 PRINT "Reactor ";:GOSUB 445
442 PRINT "It's like a maze in here.":GOTO 452
443 PRINT "Storage locker ";:GOSUB 445
444 PRINT "Not used much, but they put it here anyway.":GOTO 452
445 SET #102:INK1
446 PRINT " Exits: ";
447 IF RM(R,1)<>0THENPRINT "n ";
448 IF RM(R,2)<>0THENPRINT "s ";
449 IF RM(R,3)<>0THENPRINT "e ";
450 IF RM(R,4)<>0THENPRINT "w ";
451 PRINT :RETURN
452 PRINT :SET #102:INK1:LET ER=R:RETURN
453 PRINT :PRINT
454 REM
455 FOR X=1TO15
456 IF OB(X,2)=RANDOB(X,1)=1THENPRINT L$(X,1)
457 IF OB(X,2)=RANDOB(X,1)=0THENPRINT "You see a ";L$(X,2)
458 NEXT
459 RETURN
460 REM
461 IF M1$="i"THEN 488
462 IF M1$="l"THENLET ER=0:GOTO 41
463 REM
464 IF M1$="n"THEN 469
465 IF M1$="s"THEN 471
466 IF M1$="e"THEN 473
467 IF M1$="w"THEN 475
468 PRINT "I'm sorry, but your input wasn't understood.":GOTO 41
469 IF RM(R,1)<1THENLET B=1:GOTO 477
470 LET ER=R:LET R=RM(ER,1):GOTO 41
471 IF RM(R,2)<1THENLET B=2:GOTO 477
472 LET ER=R:LET R=RM(ER,2):GOTO 41
473 IF RM(R,3)<1THENLET B=3:GOTO 477
474 LET ER=R:LET R=RM(ER,3):GOTO 41
475 IF RM(R,4)<1THENLET B=4:GOTO 477
476 LET ER=R:LET R=RM(ER,4):GOTO 41
477 IF RM(R,B)<0THEN 479
478 GOTO 482
479 PRINT "You need to be holding an access card to go that way."
480 PRINT "The correct syntax to move through an access card door."
481 PRINT "Is 'access north,' etc.":GOTO 41
482 LET J=RND(5)
483 IF J=0THENPRINT "You can't go that way.":GOTO 41
484 IF J=1THENPRINT "That's not an exit.":GOTO 41
485 IF J=2THENPRINT "Despite your best efforts, you fail to find an exit that way.":GOTO 41
486 IF J=3THENPRINT "Nope, pick another direction.":GOTO 41
487 IF J=4THENPRINT "You can't go that way.":GOTO 41
488 REM inventory
489 PRINT "You are holding the following:":LET B=0
490 FOR X=1TO15
491 IF OB(X,2)=0THENPRINT "a ";L$(X,2):LET B=B+1
492 NEXT
493 IF B=0THENPRINT "nothing."
494 GOTO 42
495 PRINT :PRINT
496 PRINT
497 IF OB(1,2)<>0THEN 502
498 IF DT=0THENPRINT "The duct tape and patch holds! You shouldn't have much exposure.":RETURN
499 IF PA=0ANDDT=1THENLET EX=0:PRINT "As you move along in the suit, the patch shifts and comes off!"
500 PRINT "Your guts tingle as you almost feel the radiation exposure happen."
501 PRINT "If only you'd read the instructions! Well, you're a dead man walking, but you may still be able to finish the mission before you expire...":RETURN
502 LET EX=0:PRINT "Entering the reactor floor without a rad suit on is a death sentence!"
503 PRINT "But you may still be able to finish the mission before you expire...":RETURN
504 IF AC=0THENPRINT "It's already broken!":GOTO 41
505 PRINT "You snap the card in half with a decisive crunch.":LET OB(5,2)=-1
506 IF R=1ANDMP=1THEN 508
507 GOTO 41
508 PRINT :PRINT "Marchand gasps! 'You fool! You've killed us! Without that card there is no way out.' he bursts into a pallid sweat and begins pacing, ";
509 PRINT "muttering to himself. 'Marchand has never failed... Marchand can't fail...' after a few moments he holds his head in his hand and sobs."
510 PRINT :PRINT "He looks up at you and says quietly, 'There is no way out for me, or you.' He shakes his head, gets up, and walks over to the bomb. after a ";
511 PRINT "few moments of working over the controls he steps back and falls into chair in front of a console. 'You win,' he says simply, and sighs."
512 LET BD=0:PRINT "You inspect the bomb. The timer has stopped. It's over. you signal ops with your transponder, and moments later you can hear the sound of troops blow-torching through the door.":LET LM=0:GOTO 41
513 IF MD=0THEN 527
514 PRINT "Troops rush in and grab Marchand. He looks once at you with an odd expression before they drag him away. The commander, who doesn't look ";
515 PRINT "as though he's broken a sweat during the whole ordeal, walks over. 'nice op, cartright.' You consider his words, and think of uttering some ";
516 PRINT "cutting remark. But on balance, you decide, he's right. It was a nice op. you've save the state, saved the country from the horror of nuclear attack, and done it all with style."
517 PRINT :SET #102:INK5:PRINT "You win.":SET #102:INK1
518 PRINT "ÉType 'afterword' for a short afterword, or anything else to quit.Ü"
519 INPUT PROMPT"> ":U$
520 IF RTRIM$(LTRIM$(LCASE$(U$)))="afterword"THEN 522
521 GOTO 602
522 PRINT "Just in case you didn't realize it, this game was created in 2002. It is a faux-historical game, created largely because i love classic adventure games (bad parsers and all) and classic magazines."
523 PRINT "In case you're wondering, most of the 'backstory' is true -- all the locations, magazines, even the people. There was no antic Apple II "
524 PRINT "magazine, but antic, mac home journal, wired, even the sega master system are all real. just for the record, this game is copyright 2002 by Chris Charla. It is a work of fiction. Any use of real names or ";
525 PRINT "locations was done purely to enhance the verisimilitude of the fiction and shouldn't be construed in any way, by anyone, as an endorsement of this game, or whatever, by those people, magazines, darkrooms or ";
526 PRINT "videogame systems. Thanks to Mike Mika, Carrie Shepherd and Oscar Charla.":GOTO 602
527 PRINT "Troops rush in. they stop, almost disappointed, when they see his lifeless body on the floor. the commander, who doesn't look as though he's broken a sweat during the whole ordeal, walks over. 'nice ";
528 PRINT "op, cartright.' You consider his words, and think of uttering some cutting remark. But on balance, you decide, he's right. It was a nice op. you've save the state, saved the country from the horror of nuclear ";
529 PRINT "attack, and done it all with style."
530 PRINT :SET #102:INK3:PRINT "You win.":SET #102:INK1
531 PRINT "ÉType 'afterword' for a short afterword, or anything else to quit.Ü"
532 INPUT PROMPT"> ":U$
533 IF RTRIM$(LTRIM$(LCASE$(U$)))="afterword"THEN 522
534 GOTO 602
535 REM
536 IF BD=0THEN 540
537 PRINT "An agent needs to never lose his cool. You just did. Now there's a bomb set to go off that will kill tens of thousands, and your failure, ";
538 PRINT "your anger, prevented you from stopping it. Marchand is dead, but it's meaningless - one death among thousands. You have failed humanity. Your only regret is that you don't have another bullet ";
539 PRINT "in the gun for yourself.":GOTO 602
540 PRINT "Now that it's over, sweat is pouring down your face. You wonder what would have become of him. A trial? Too risky. no, it's likely that Marchand would've spilled his guts and disappeared into some kind of ";
541 PRINT "protection program. Not fair. Not after this. There was vladistan, but this was different. This required real justice. You look at Marchand one last time, as he lays bleeding on the floor. He looks ";
542 PRINT "in your eyes and nods slightly. It's better this way, for both of you."
543 LET MP=-10:GOTO 41
544 REM
545 IF BD=0THEN 548
546 PRINT "Maybe Marchand is right. Maybe there's no point. Who cares about the bomb."
547 PRINT "Who cares about anything?":GOTO 602
548 PRINT "Vladistan. Marchant was right about one thing. It never left. But unlike Marchand, you still had a job to do. Now that was over, and the bomb ";
549 PRINT "defused, and it was time to take one more sick monster out of the world."
550 PRINT "you.":GOTO 602
551 REM
552 IF BD=0THEN 556
553 PRINT "Despite your best efforts, the radiation overcomes you..."
554 PRINT "Your last thoughts are that your fate today will soon befall tens of thousands of your countrymen. you have failed."
555 GOTO 557
556 PRINT "As the radiation overcomes you and you collapse, you take solace in knowing that you've at least finished the mission and saved tens of thousands from the painful death you are now experiencing..."
557 GOTO 602
558 REM
559 LET X=RND(15)
560 LET X=X+1
561 IF X=1ORX=5ORX=4ORX=16ORX=17THEN 559
562 LET ML=X
563 RETURN
564 REM
565 REM
566 REM IF OB(6,2)=0 THEN 8300
567 SET #102:INK5:PRINT "Marchand enters the room!":SET #102:INK1
568 LET X=RND(6)+1
569 ON XGOTO 570, 572, 574, 576, 577, 579
570 PRINT "He leers at you. 'you think you have trapped me, no? I assure you, i have no intention of dying here. i vill find my out, while you stay here to ";
571 PRINT "disarm Zee bomb. Which you will not do, by Zee way.'":GOTO 580
572 PRINT "Marchand smirks. 'When Zee bomb goes off, this facility will be destroyed."
573 PRINT "at zat point, no matter what you do, Zee reactor will be headed for zee how do you say -- critical point? I will be safely away.'":GOTO 580
574 PRINT "He doesn't seem entirely confident at first. 'There are many agents guarding Zee ways out.' He brightens. 'But Marchand has never been captured!"
575 PRINT "My mission will be a success. The facility will be destroyed, and i will not.'":GOTO 580
576 PRINT "He looks at you. 'Why are you steel here, mon am i? Perhaps i shall follow you out. I think you have no more desire to die than i?":GOTO 580
577 PRINT "He holds up a shattered access card. 'I have a confession to make. Evenifi wanted to disarm Zee bomb, i couldn't. A guard, now dead, of course, saw to ";
578 PRINT "that. No, ze lonely bomb will sit in ze control room until it's time to blow.'":GOTO 580
579 PRINT "Marchand checks his watch. 'How long, how long... enough for me, but not enough for you!'":GOTO 580
580 PRINT :LET X=RND(5)+1
581 ON XGOTO 582, 583, 584, 585, 586, 587
582 PRINT "If only you had some way to threaten Marchand, to get him to move where you wanted him to. But you don't. yet...":PRINT :GOTO 61
583 PRINT "You consider lunging for Marchand, but no... the chance he could win a physical encounter, however small, is too much. you need a decisive victory.":PRINT :GOTO 61
584 PRINT "There will be time to deal with Marchand when the time is right. You turn away.":PRINT :GOTO 61
585 PRINT "You ponder Marchand. In vladistan, you were allies. What happened to the man to turn him to nuclear blackmail? no, not blackmail... simple terrorism.":PRINT :GOTO 61
586 PRINT "You can't take it, and throw at punch at marchand. he dives out of the way with the speed of a man who has spent years in training.":PRINT :GOTO 61
587 PRINT "You know there's no way out for Marchand. But you consider... this may be the end of the line for both of you and for half the state.":PRINT :GOTO 61
588 GOTO 61
589 REM
590 GOTO 41
591 PRINT "As you get ready for the mission, the commander briefs you one last time."
592 PRINT "'Cartright, we know it's Marchand in there. He's no suicide, he wants to' come out. But we've got him bottled up like a rat. Your job is simple.";CHR$(248);
593 PRINT "Disarm the bomb. Or convince marchand to do it for you. Either way, we both know Marchand is one of the top agents in the world.";CHR$(248);
594 PRINT "We can't take the chance that he'd be able to disarm you, or escape the way you came in. So we're welding you in, and sending you in unarmed.";CHR$(248);
595 PRINT "See if you can talk to Marchand. You two have a history, right?' you think of vladistan. History is putting it mildly. '...and if that doesn't ";
596 PRINT "work, try threatening him. I don't have to tell you just how many are riding on this, do i? I don't have to explain what will happen if a bomb goes off in the control room of this plant, do i?'";CHR$(248);
597 PRINT "No, he doesn't, but of course he does anyway. 'Thousands dead. tens of thousands. Vast areas of land unusable for thousands of years. End of the ";
598 PRINT "world stuff here. That's what we're dealing with, end of the world stuff.'";CHR$(248);
599 PRINT "No, you're not. You're dealing with Marchand. You look at the commander and nod, then head towards the tunnel..."
600 SET #102:INK1
601 GOTO 41
602 PRINT :SET #102:INK5:PRINT "Game over.":SET #102:INK1
603 PRINT :PRINT "Another game? (y/n)"
604 DO
605 LET M$=LCASE$(INKEY$)
606 LOOP UNTILM$="y"ORM$="n"
607 IF M$="y"THENRUN
608 CLEAR FKEYS:SET 26,0:SET 27,0:TEXT 40:SET 8,0
609 CLOSE #1
610 PRINT "Bye..."
611 END
612 IF M2$="kit"THENLET M2$="pat"
613 IF M2$="bar"THENLET M2$="cro"
614 IF M2$="duc"THENLET M2$="tap"
615 IF M2$="car"THENLET M2$="acc"
616 IF M2$="swi"THENLET M2$="ala"
617 IF M2$="bod"THENLET M2$="cor"
618 IF M2$="pri"THENLET M2$="blu"
619 IF M2$="kit"THENLET M2$="pat"
620 IF M2$="me"THENLET M2$="sel"
621 IF M2$="loc"THENLET M2$="cas"
622 IF M2$="pic"THENLET M2$="pho"
623 RETURN
624 END
625 DATA 0,-1,0,0,-1,0,3,0,0,19,6,2,0,0,5,0,0,-1,0,4,0,0,7,3,-1,11,8,6,0,0,9,7,0,10,0,8,9,-1,0,0
626 DATA 7,13,0,0,0,15,13,0,11,14,0,12,13,0,0,15,12,0,14,0,6,17,0,0,16,0,0,0,0,0,19,0,3,20,0,18,19,0,0,0
627 DATA -1,-1,0,0,-1,25,0,0,0,27,24,26,0,0,25,23,22,28,0,24,0,31,0,23,24,29,29,23,25,30,0,0,27,27,30,0,28,0,0,29,26,0,0,0
628 DATA 1,10,1,31,1,5,1,16,1,-1,1,-1,0,-1,1,-2,1,-4,1,-5,1,-3,1,-7,1,-1,1,-1,1,-9
629 DATA "Worn by a corpse is a holed radiation suit.","suit","This disused closet is empty, except for an old crowbar in the back."
630 DATA "crowbar","On a desk is a rad suit patch kit.","patch","A roll of duct tape hangs here from a well, a duct.","tape"
631 DATA "An access card, fallen from the safe, lies on the floor.","access card","A gun is lying on the floor here."
632 DATA "gun","initial description of combination","combination","initial description of safe","safe"
633 DATA "initial description of case","case","initial description of corpse"
634 DATA "corpse","initial description of guffin3","blue prints","initial description of guffin4","photo"
635 DATA "initial description of guffin5","guffin5","initial description of guffin6","guffin6","initial description of guffin7","bomb"
636 DATA "go","nor","sou","eas","wes","tal","rea","loo","exa","sea","inv","hea","dia","app","sho","kil"
637 DATA "acc","put","dro","rem","get","tak","clo","unl","bre","pry","sma","hel","ope","thr","sca","use","xyz","fuc","shi","pis"
638 DATA 1,1,1,1,1,2,3,3,3,3,4,5,5,6,7,7,8,6,9,9,10,10,11,12,13,13,13,16,14,15,15,16,17,18,18,18
EXOS header pos/serial: #1 at 0x91c6
EXOS type/header: 0xa [00 0A 00 00 00 00 00 00 00 00 00 00 00 00 00 00]
EXOS type determined: End of module
End of FILE parsing, because: End-of-module header got (type=10)
Enterprise-128 EXOS file analyzer, lister and disassembler v0.5.8 ©2012,2013 "LGB" Gábor Lénárt (lgb at-sign lgb dot hu)