epbas.lgb.hu :: Enterprise-128 EXOS file analyzer, lister and disassembler

File name: /tmp/phpjOf5Rm (2651 bytes)
Options: bin=None cset='UK' dasm='' html='' info='' out='/tmp/phpjOf5Rm.out'
EP-ASCII: UK
EXOS header pos/serial: #0 at 0x0
EXOS type/header: 0x4 [00 04 3B 0A 00 00 00 00 00 00 00 00 00 00 00 00]
EXOS type determined: IS-BASIC program (single)

Program: 0x0, size: 0xa3b bytes.
  100 PROGRAM "Hanoi.bas"
  105 SET KEYCLICKOFF
  110 STRING K$(20)
  120 NUMERIC K,L,M(3),POZ(3),COL(3)
  130 LET K=13 ! Az oszlopok maximalis magassaga
  140 LET L=INT(K/2) ! A legnagyobb korong szelessege
  150 LET POZ(1)=7-L:LET POZ(2)=20-L:LET POZ(3)=33-L
  160 LET COL(0)=15 ! A korongok szine
  170 LET COL(1)=11:LET COL(2)=3:LET COL(3)=7
  180 CALL GRAPH
  190 CLEAR SCREEN
  200 PRINT #101,AT20,1:;
  210 SET INKCOL(1)
  220 PRINT #101:"     REZ     ";
  230 SET INKCOL(2)
  240 PRINT #101:"    ARANY    ";
  250 SET INKCOL(3)
  260 PRINT #101:"    EZUST    ";
  270 DO 
  280   PRINT AT1,1:"Hany korong van a rezlapon";
  285   INPUT N
  290 LOOP WHILEN<1ORN>K
  300 CALL IDO(2^N-1)
  310 LET M(1)=N:LET M(2),M(3)=0
  320 FOR I=NTO0STEP-1
  330   SET INKCOL(1)
  340   PRINT #101,AT(19-N+I),POZ(1):K$(0);
  350   SET INKCOL(2)
  360   PRINT #101,AT(19-N+I),POZ(2):K$(0);
  370   SET INKCOL(3)
  380   PRINT #101,AT(19-N+I),POZ(3):K$(0);
  390 NEXT 
  400 SET INKCOL(0)
  410 FOR I=NTO1STEP-1
  420   PRINT #101,AT(19-N+I),POZ(1):K$(I);
  430 NEXT 
  440 CALL TORONY(N,1,2,3)
  450 PRINT AT3,1:2^N-1;" lepessel megoldottam!   ";
  460 PING 
  470 END 
  480 DEF TORONY(P,ELSO,MAS,HAR)
  490   IF P>1THENCALL TORONY(P-1,ELSO,HAR,MAS)
  500   CALL KORONG(P,ELSO,MAS)
  510   IF P>1THENCALL TORONY(P-1,HAR,MAS,ELSO)
  520 END DEF 
  530 DEF KORONG(Q,HONNAN,HOVA)
  540   GET A$
  550   IF A$=""THENWAIT 1
  570   SET INKCOL(HONNAN)
  580   PRINT #101,AT(20-M(HONNAN)),POZ(HONNAN):K$(0);
  590   LET M(HONNAN)=M(HONNAN)-1
  600   LET M(HOVA)=M(HOVA)+1
  610   SET INKCOL(0)
  620   PRINT #101,AT(20-M(HOVA)),POZ(HOVA):K$(Q);
  630 END DEF 
  640 DEF GRAPH
  650   GRAPHICS ATTRIBUTE
  660   SET CHARACTER128,24,24,24,24,24,24,24,24,24
  670   SET CHARACTER129,0,15,15,15,15,15,15,15,15
  680   SET CHARACTER130,0,255,255,255,255,255,255,255,255
  690   SET CHARACTER131,0,240,240,240,240,240,240,240,240
  700   LET K$(0)="      "&CHR$(128)&"      "
  710   FOR I=1TOK
  720     LET A$=""
  730     FOR J=1TO(K-I)/2
  740       LET A$=A$&" "
  750     NEXT 
  760     IF MOD(I,2)=0THEN
  770       LET A$=A$&CHR$(129)
  780       FOR J=1TOI-1
  790         LET A$=A$&CHR$(130)
  800       NEXT 
  810       LET A$=A$&CHR$(131)
  820     ELSE 
  830       FOR J=1TOI
  840         LET A$=A$&CHR$(130)
  850       NEXT 
  860     END IF 
  870     FOR J=1TO(K-I)/2
  880       LET A$=A$&" "
  890     NEXT 
  900     LET K$(I)=A$
  910   NEXT 
  920 END DEF 
  930 DEF IDO(M)
  940   NUMERIC E,H,N,O,P
  950   LET P=INT(M/60):LET M=MOD(M,60)
  960   LET O=INT(P/60):LET P=MOD(P,60)
  970   LET N=INT(O/24):LET O=MOD(O,24)
  980   LET E=INT(N/365)
  990   PRINT AT3,1:"Ehhez ";
 1000   IF E>0THENPRINT E;" ev, ";
 1010   IF N>0THENPRINT N;" nap, ";
 1020   IF O>0THENPRINT O;" ora, ";
 1030   IF P>0THENPRINT P;" perc es ";
 1040   PRINT M;"masodperc szukseges!"
 1050 END DEF 

EXOS header pos/serial: #1 at 0xa4b
EXOS type/header: 0xa [00 0A 00 00 00 00 00 00 00 00 00 00 00 00 00 00]
EXOS type determined: End of module


End of FILE parsing, because: End-of-module header got (type=10)