epbas.lgb.hu :: Enterprise-128 EXOS file analyzer, lister and disassembler
File name: /tmp/php73GS6h (12793 bytes)
Options: bin=None cset='UK' dasm='' html='' info='' out='/tmp/php73GS6h.out'
EP-ASCII: UK
EXOS header pos/serial: #0 at 0x0
EXOS type/header: 0x4 [00 04 D9 31 00 00 00 00 00 00 00 00 00 00 00 00]
EXOS type determined: IS-BASIC program (single)
Program: 0x0, size: 0x31d9 bytes.
10 PROGRAM "hoszuks.bas"
12 OUT 191,12
15 LET HH=25 ! helyisegek szama
20 STRING D$*11,INK0$*3,INK1$*3,INK2$*3,BILL$*1,HN$(HH)*12
30 NUMERIC MN,I,J,KK,LL,TOT,HS
40 NUMERIC T(HH,3),K(HH,2),P(HH,3),S(HH),L(HH),M(HH)
50 NUMERIC V(HH),E(HH),X(HH),G(HH),B(HH),H(HH),O(HH)
60 NUMERIC R(HH),Z(HH,8),U(HH,8),F(HH,8),C(HH,8),A(HH,8),Y(HH,8)
70 NUMERIC D(HH*8*4),Q(HH*8*4),W(HH*8*4)
75 SET STATUSOFF
80 LET INK0$=CHR$(27)&"I"&CHR$(0)
85 LET INK1$=CHR$(27)&"I"&CHR$(4)
90 LET INK2$=CHR$(27)&"I"&CHR$(2)
95 LET TOT=0:LET HS=0
99 ! :12345678901234567890123456789012345678
100 IMAGE :Kivånt höfok= +££.£æC Méretek=££.£X££.£X££.£=££££.£m3
105 IMAGE :## ££./££ helyiség, <££££££££££££
110 IMAGE :<£££££££££££ £ >£££££££ -££.£ +££.£ >££££££ -££££.£
120 SET CHARACTER151,28,54,54,28,0,0,0,0,0
130 SET CHARACTER137,16,24,44,44,44,70,70,255,0
200 ! a fo ciklus
210 CALL INIT
240 DO
250 LET MN=FOMENU ! Fomenu hivasa parameter atadassal
300 SELECT CASEMN
310 CASE 1 ! uj adatok
320 CALL BEVITEL
350 CASE 2 ! betoltes
360 CALL BETOLTES
390 CASE 3 ! kimentes
400 CALL KIMENTES
430 CASE 4 ! javitas
440 CALL JAVIT
470 CASE 5 ! kiirasok
480 CALL KIIRAS
485 CALL SZAMOL
490 CASE 6
500 CALL HELP
510 CALL BILL
520 TEXT 40
550 CASE ELSE ! prg vege
560 TEXT
570 PRINT :PRINT "Remélem segitettem."
575 PRINT :PRINT " Köszönöm a türelmed!"
580 END
590 END SELECT
599 LOOP
600 DEF BEVITEL
605 DO
610 TEXT 80:PRINT :PRINT
615 INPUT PROMPT"Helyisegek szama?: ":HS
620 LOOP UNTILHS>0ANDHS<=HH
625 LET T0=0:LET SS=1
630 FOR I=1TOHS
635 CALL HELYISEG(I)
640 CALL FALAK(I)
700 PRINT :PRINT "Akarsz potlekokkal szamolni? (I=igen, mas=nem)"
710 CALL BILL
720 IF BILL$="I"THEN
730 CALL POTLEKOK(I)
740 END IF
750 NEXT
755 CALL SZAMOL
799 END DEF
800 DEF HELYISEG(I)
805 DO
810 TEXT
815 PRINT TAB(15);I;". helyiseg"
820 PRINT TAB(15);"--------------":PRINT
825 INPUT PROMPT"A helyiseg megnevezese (max.10 kar.):":HN$(I)
830 PRINT
835 PRINT "A helyiseg meretei :"
840 PRINT "-------------------"
845 INPUT PROMPT"hosszusag (m) :":L(I)
850 INPUT PROMPT"szelesseg (m) :":S(I)
855 INPUT PROMPT"magassag (m) :":M(I)
860 LET V(I)=ROUND(L(I)*M(I)*S(I),2)
865 PRINT "legterfogat :";V(I);"m3":PRINT
870 INPUT PROMPT"A helyiseg megkivant homerseklete (æC):":T(I,3)
875 INPUT PROMPT"A fodem hoatbocsatasi tenyezoje (W/m2*K):":K(I,1)
880 INPUT PROMPT"A felso legter homerseklete (æC):":T(I,1)
885 INPUT PROMPT"A padlo hoatbocsatasi tenyezoje (W/m2*K):":K(I,2)
890 INPUT PROMPT"Az also legter homerseklete (æC):":T(I,2)
895 SET #102:INK2
900 PRINT :PRINT :PRINT "Helyesek az adatok? (i=igen, mas=nem)"
905 CALL BILL
910 SET #102:INK0
915 LOOP UNTILBILL$="I"
918 CALL FALAK(I)
920 END DEF
925 DEF FALAK(I)
930 DO
935 TEXT
940 PRINT TAB(15);STR$(I);". helyiseg"
945 PRINT TAB(15);"---------------":PRINT :PRINT
950 INPUT PROMPT"Hatarolo legterek szama :":R(I)
955 LOOP WHILER(I)<1ORR(I)>8
960 !
965 FOR J=1TOR(I)
970 CALL FALRESZ(I,J)
1110 NEXT
1112 END DEF
1275 DEF FALRESZ(I,J)
1280 DO
1285 TEXT
1290 PRINT :PRINT " ";STR$(I);". helyiseg, ";STR$(J);". falresz"
1295 PRINT "----------------------------------":PRINT
1300 INPUT PROMPT"hatarolo legter homerseklete (æC):":Z(I,J)
1305 INPUT PROMPT"a falresz hosszusaga (m):":FH
1310 INPUT PROMPT"a falresz magassaga (m):":FM
1315 LET F(I,J)=FH*FM:PRINT "a falresz teljes felulete :";F(I,J);"m2"
1320 INPUT PROMPT"a fal hoatbocsatasi tenyezoje (W/m2*K):":A(I,J)
1325 DO
1330 PRINT :INPUT PROMPT"nyilaszarok szama :":Y(I,J)
1335 LOOP WHILEY(I,J)<0ORY(I,J)>4
1340 IF Y(I,J)<>0THEN
1345 FOR KK=1TOY(I,J)
1348 CALL NYILZAR(I,J,KK)
1350 NEXT
1355 END IF
1360 PRINT :PRINT #102:INK2$;"Helyesek az adatok? (i=igen, mas=nem)";INK0$
1365 CALL BILL
1367 LOOP UNTILBILL$="I"
1369 END DEF
1370 DEF NYILZAR(I,J,K)
1375 PRINT :PRINT " ";KK;". nyilaszaro"
1380 PRINT " -----------------"
1385 INPUT PROMPT"A nyilaszaro hossza (m): ":FH
1390 INPUT PROMPT"A nyilaszaro magassaga (m): ":FM
1395 LET D(I*HH+J*8+K)=FH*FM:PRINT "A nyilaszaro felulete (m2):";D(I*HH+J*8+K)
1400 INPUT PROMPT"A nyilaszaro hoatbocsatasi tenyezoje (W/(m2*K)): ":Q(I*HH+J*8+K)
1405 END DEF
1450 DEF POTLEKOK(I)
1455 DO
1460 INPUT PROMPT"Egtajpotlek (%) :":E(I)
1465 INPUT PROMPT"Szelpotlek (%) :":X(I)
1470 INPUT PROMPT"Felfutesi potlek (%) :":G(I)
1475 INPUT PROMPT"kurtohatas potlek (%) :":H(I)
1480 PRINT :PRINT #102:INK2$;"Helyesek az adatok? (i=igen, mas=nem)";INK0$
1485 CALL BILL
1490 LOOP UNTILBILL$="I"
1495 END DEF
1500 DEF SZAMOL
1505 LET TOT=0
1510 FOR I=1TOHS
1520 LET P(I,3)=0:LET O(I)=1 ! helyisegP=0, potlekok=0
1530 LET P(I,1)=L(I)*S(I)*K(I,1)*(T(I,3)-T(I,1)) ! mennyezetP
1540 LET P(I,3)=P(I,3)+P(I,1) ! helyisegP=helyisegP+mennyezetP
1550 LET P(I,2)=L(I)*S(I)*K(I,2)*(T(I,3)-T(I,2)) ! padloP
1560 LET P(I,3)=P(I,3)+P(I,2) ! helyisegP=helyisegP+padloP
1570 LET V(I)=L(I)*S(I)*M(I) ! legkobmeter
1580 FOR J=1TOR(I) ! falak
1590 LET C(I,J)=F(I,J) ! falresz felulete
1600 FOR KK=1TOY(I,J) ! nyilaszarok
1610 LET C(I,J)=C(I,J)-D(I*HH+J*8+KK) ! fal-nyilaszaro felulet
1620 LET W(I*HH+J*8+KK)=D(I*HH+J*8+KK)*Q(I*HH+J*8+KK)*(T(I,3)-Z(I,J)) ! nyilaszaroP
1630 LET P(I,3)=P(I,3)+W(I*HH+J*8+KK) ! helyisegP=helyisegP+nyilaszaroP
1640 NEXT
1650 LET U(I,J)=C(I,J)*A(I,J)*(T(I,3)-Z(I,J)) ! falreszP
1660 LET P(I,3)=P(I,3)+U(I,J) ! helyisegP=helyisegP+falreszP
1670 NEXT
1680 LET O(I)=O(I)+(E(I)+X(I)+G(I)+B(I)+H(I))/100 ! potlekok osszesen
1690 LET P(I,3)=P(I,3)*O(I) ! helyisegP=helyisegP*potlekok
1700 LET TOT=TOT+P(I,3) ! totalP=totalP+helyisegP
1710 NEXT
1799 END DEF
1800 DEF STRG$(X,Y)
1810 STRING A$*15,B$*15,C$*20
1820 LET B$=" "&STR$(IP(X))&"."
1830 LET C$=STR$(ROUND(FP(X),Y))&"0000000"
1840 LET A$=B$(LEN(B$)-3:LEN(B$))&C$(2:Y+1)
1850 LET STRG$=A$
1999 END DEF
2000 DEF JAVIT
2010 !
2020 TEXT 80
2030 PRINT AT4,1:"Hånyas helyiséget mutassam?"
2040 INPUT AT5,1,PROMPT"Az egész lakås höszükségletéhez 'T':":W$
2050 LET XX=VAL(W$)
2060 IF UCASE$(W$)<>"T"ANDXX<1ANDXX>HSTHEN
2070 PRINT "!! Hibås helyiség szåm !!":PRINT
2080 GOTO 2030
2090 END IF
2100 IF W$="T"THENLET XX=0
2110 CALL MEGJELENIT(XX)
2120 CALL MODOSIT
2480 CALL BILL
2490 END DEF
2500 DEF MODOSIT
2520 PRINT #102,AT1,70:INK2$;"Modositås";
2530 PRINT #102,AT2,70:INK2$;"----------";
2540 PRINT #102,AT3,70:INK2$;"Helyiség+ ";
2545 PRINT #102,AT4,70:INK2$;"Helyiség- ";
2550 PRINT #102,AT5,70:INK2$;"Falrész + ";
2555 PRINT #102,AT6,70:INK2$;"Falrész - ";
2560 PRINT #102,AT7,70:INK2$;"Nyilåsz.+ ";
2565 PRINT #102,AT8,70:INK2$;"Nyilåsz.- ";
2570 PRINT #102,AT9,70:INK2$;"Méret ";
2580 PRINT #102,AT10,70:INK2$;"Belsö æC ";
2590 PRINT #102,AT11,70:INK2$;"Külsö æC ";
2600 PRINT #102,AT12,70:INK2$;"k-tenyezö ";
2610 PRINT #102,AT13,70:INK2$;"Potlékok ";
2999 END DEF
3000 DEF MEGJELENIT(I)
3200 !
3210 IF I=0THEN
3220 PRINT :PRINT "A lakås teljes höszükséglete :";INT(TOT);"W"
3230 PRINT :PRINT "Nyomj egy billentyüt..."
3240 ! CALL BILL
3250 EXIT DEF
3260 END IF
3270 TEXT
3280 PRINT USING 105:I,HS,HN$(I)
3300 PRINT USING 100:T(I,3),L(I),S(I),M(I),V(I)
3310 PRINT "==============================================================="
3320 PRINT "Hatårolo nyilås- felület Külsö Çt k Fütési szerkezet zåro m2 höm.æC æC W/m2*K telj. W"
3330 PRINT "................................................................"
3340 PRINT AT7,1:;
3350 PRINT USING 110:"Mennyezet","",STRG$(L(I)*S(I),2),T(I,1),T(I,3)-T(I,1),STRG$(K(I,1),2),P(I,1)
3360 PRINT USING 110:"Padlo","",STRG$(L(I)*S(I),2),T(I,2),T(I,3)-T(I,2),STRG$(K(I,2),2),P(I,2)
3370 LET HA=1
3380 FOR J=1TOR(I)
3390 LET HA=HA+1
3400 IF MOD(HA,15)=0THEN
3410 END IF
3420 PRINT USING 110:"Falrész-"&STR$(J),"",STRG$(C(I,J),2),Z(I,J),T(I,3)-Z(I,J),STRG$(A(I,J),2),U(I,J)
3430 FOR KK=1TOY(I,J)
3440 LET HA=HA+1
3450 IF MOD(HA,15)=0THEN
3460 END IF
3470 PRINT USING 110:" '--→",KK,STRG$(D(I*HH+J*8+KK),2),Z(I,J),T(I,3)-Z(I,J),STRG$(Q(I*HH+J*8+KK),2),W(I*HH+J*8+KK)
3480 NEXT
3490 NEXT
3500 PRINT "==============================================================="
3510 PRINT "Potlékok: Egtåj:";E(I);" Szél:";X(I);" Felfütés:";G(I);" Belmag.:";B(I);" Kürtöh.:";H(I)
3520 PRINT "A helyiség höszükséglete:";INT(P(I,3));"W,";INT(P(I,3)/V(I));"W/m3"
3540 END DEF
4000 DEF KIIRAS
4005 STRING SZAM$*2
4010 TEXT 80
4015 LET I=1:LET SZAM$="":LET NUM=1
4020 DO
4025 CALL MEGJELENIT(I)
4030 CALL BILL
4035 IF BILL$=CHR$(176)ORBILL$=CHR$(188)THEN
4040 LET I=I+1:LET I=MIN(I,HS)
4045 END IF
4050 IF BILL$=CHR$(180)ORBILL$=CHR$(184)THEN
4055 LET I=I-1:LET I=MAX(I,1)
4060 END IF
4065 IF BILL$=CHR$(27)ORBILL$=CHR$(13)THEN
4070 EXIT DEF
4075 END IF
4080 IF BILL$>="0"ANDBILL$<="9"THEN
4085 PRINT AT1,1:BILL$;
4090 LET SZAM$=SZAM$&BILL$
4095 PRINT AT1,1:SZAM$;
4100 CALL BILL
4105 IF BILL$<"0"ANDBILL$>"9"THEN 4100
4110 LET SZAM$=SZAM$&BILL$
4115 PRINT AT1,1:SZAM$
4120 LET NUM=VAL(SZAM$)
4125 LET SZAM$=""
4130 IF NUM<=HSANDNUM>0THENLET I=NUM:LET NUM=0
4135 END IF
4140 LOOP
4145 END DEF
6000 DEF BETOLTES
6005 TEXT 40
6010 PRINT :PRINT "Tegyél be kazettåt és inditsd el a magnot ha szükséges..."
6015 PRINT :PRINT ">>>> Adatållomåny betöltése <<<<"
6020 INPUT PROMPT"File név :":D$
6025 POKE 56,201
6030 OPEN #1:D$ACCESSINPUT
6035 PRINT " 1/5. ";
6040 INPUT #1:D$
6045 INPUT #1:HS
6050 INPUT #1:TOT
6055 FOR I=1TOHH
6060 INPUT #1:S(I),L(I),M(I),V(I),E(I),X(I),G(I),B(I),H(I),O(I),R(I)
6065 INPUT #1:HN$(I)
6070 NEXT
6075 PRINT " 2/5. ";
6080 FOR I=1TOHH
6085 FOR J=1TO8
6090 INPUT #1:A(I,J),C(I,J),F(I,J),U(I,J),Y(I,J),Z(I,J)
6095 NEXT
6100 NEXT
6105 PRINT " 3/5. ";
6110 FOR I=1TOHH
6115 FOR J=1TO3
6120 INPUT #1:T(I,J),P(I,J)
6125 NEXT
6130 NEXT
6135 PRINT " 4/5. ";
6140 FOR I=1TOHH
6145 FOR J=1TO2
6150 INPUT #1:K(I,J)
6155 NEXT
6160 NEXT
6165 PRINT " 5/5. ";
6170 FOR I=1TOHH*8*4
6175 INPUT #1:D(I),Q(I),W(I)
6180 NEXT
6185 CLOSE #1
6190 POKE 56,245
6195 END DEF
6300 DEF KIMENTES
6305 TEXT 40
6310 PRINT :PRINT "Tegyél be kazettåt és inditsd el a magnot ha szükséges..."
6315 PRINT :PRINT ">>>> Adatållomåny kimentése <<<<"
6320 INPUT PROMPT"File név :":D$
6325 POKE 56,201
6330 OPEN #1:D$ACCESSOUTPUT
6335 PRINT " 1/5. ";
6340 PRINT #1:D$
6345 PRINT #1:HS
6350 PRINT #1:TOT
6355 FOR I=1TOHH
6360 PRINT #1:S(I)
6365 PRINT #1:L(I)
6370 PRINT #1:M(I)
6375 PRINT #1:V(I)
6380 PRINT #1:E(I)
6385 PRINT #1:X(I)
6390 PRINT #1:G(I)
6395 PRINT #1:B(I)
6400 PRINT #1:H(I)
6405 PRINT #1:O(I)
6410 PRINT #1:R(I)
6415 PRINT #1:HN$(I)
6420 NEXT
6425 PRINT " 2/5. ";
6430 FOR I=1TOHH
6435 FOR J=1TO8
6440 PRINT #1:A(I,J)
6445 PRINT #1:C(I,J)
6450 PRINT #1:F(I,J)
6455 PRINT #1:U(I,J)
6460 PRINT #1:Y(I,J)
6465 PRINT #1:Z(I,J)
6470 NEXT
6475 NEXT
6480 PRINT " 3/5. ";
6485 FOR I=1TOHH
6490 FOR J=1TO3
6495 PRINT #1:T(I,J)
6500 PRINT #1:P(I,J)
6505 NEXT
6510 NEXT
6515 PRINT " 4/5. ";
6520 FOR I=1TOHH
6525 FOR J=1TO2
6530 PRINT #1:K(I,J)
6535 NEXT
6540 NEXT
6545 PRINT " 5/5. ";
6550 FOR I=1TOHH*8*4
6555 PRINT #1:D(I)
6560 PRINT #1:Q(I)
6565 PRINT #1:W(I)
6570 NEXT
6575 CLOSE #1
6580 POKE 56,245
6585 END DEF
8000 DEF BILL
8010 DO
8030 GET BILL$
8040 LOOP WHILEBILL$=""
8050 LET BILL$=UCASE$(BILL$)
8090 END DEF
8500 DEF INIT
8502 POKE 56,201
8505 PRINT "A våltozok inicializålåsa - 1/5, ";
8510 FOR I=1TOHH
8520 LET S(I)=0:LET L(I)=0:LET M(I)=0:LET V(I)=0
8530 LET E(I)=0:LET X(I)=0:LET G(I)=0:LET B(I)=0
8540 LET H(I)=0:LET O(I)=0:LET R(I)=0:LET HN$(I)=".."&STR$(I)&".."
8550 NEXT
8555 PRINT "2/5, ";
8560 FOR I=1TOHH
8570 FOR J=1TO8
8580 LET Z(I,J)=0:LET U(I,J)=0:LET F(I,J)=0
8590 LET C(I,J)=0:LET A(I,J)=0:LET Y(I,J)=0
8600 NEXT
8610 NEXT
8615 PRINT "3/5, ";
8620 FOR I=1TOHH
8630 FOR J=1TO3
8640 LET T(I,J)=0:LET P(I,J)=0
8650 NEXT
8660 NEXT
8665 PRINT "4/5, ";
8670 FOR I=1TOHH
8680 FOR J=1TO2
8690 LET K(I,J)=0
8700 NEXT
8710 NEXT
8715 PRINT "5/5"
8720 FOR I=1TOHH*8*4
8750 LET D(I)=0:LET Q(I)=0:LET W(I)=0
8780 NEXT
8800 LET HS=0:LET TOT=0:LET D$="haz.dat"
8980 POKE 56,245
8990 PRINT "Inicializålås vége..."
8999 END DEF
9000 DEF FOMENU
9005 NUMERIC Y,YR
9010 TEXT 40
9020 PRINT " ■■■■■ HÖSZÜKSEGLET-SZÅMITÅS ■■■■■":PRINT
9030 PRINT #102:
9040 PRINT #102:INK2$;" 1 ";INK0$;"Uj adatok bevitele"
9050 PRINT #102:
9060 PRINT #102:INK2$;" 2 ";INK0$;"Adatok betöltése tårolorol"
9070 PRINT #102:
9080 PRINT #102:INK2$;" 3 ";INK0$;"Adatok rögzitése tårolora"
9090 PRINT #102:
9100 PRINT #102:INK2$;" 4 ";INK0$;"Adatok javitåsa"
9110 PRINT #102:
9120 PRINT #102:INK2$;" 5 ";INK0$;"Eredmények megjelenitése"
9130 PRINT #102:
9140 PRINT #102:INK2$;" 6 ";INK0$;"Rövid leirås "
9150 PRINT #102:
9160 PRINT #102:INK2$;" 7 ";INK0$;"Program befejezése"
9170 PRINT #102:
9180 LET Y=5:LET YR=Y
9190 DO
9200 PRINT #102,AT2+YR*2,2:" "
9210 PRINT #102,AT2+Y*2,2:">>>"
9220 CALL BILL
9230 SELECT CASEBILL$
9240 CASE CHR$(176) ! fel
9250 LET YR=Y:LET Y=Y-1:LET Y=MAX(1,Y)
9260 CASE CHR$(180) ! le
9270 LET YR=Y:LET Y=Y+1:LET Y=MIN(7,Y)
9280 CASE CHR$(32),CHR$(13) ! space,enter
9290 EXIT DO
9300 CASE ELSE
9310 END SELECT
9320 LOOP
9330 LET FOMENU=Y
9340 END DEF
9500 DEF HELP
9505 TEXT 80
9799 END DEF
EXOS header pos/serial: #1 at 0x31e9
EXOS type/header: 0xa [00 0A 00 00 00 00 00 00 00 00 00 00 00 00 00 00]
EXOS type determined: End of module
End of FILE parsing, because: End-of-module header got (type=10)
Enterprise-128 EXOS file analyzer, lister and disassembler v0.5.8 ©2012,2013 "LGB" Gábor Lénárt (lgb at-sign lgb dot hu)